Wordの脚注と括弧書きを相互に変換するマクロ

stabucky — Wed, 20 Feb 2013 11:55:41 +0000

概要
マクロ

概要

Wordの脚注部分を本文中に移動させるマクロを考えてみました。
脚注は注意書きが各ページの下部に表示されるイメージですが、これを括弧で括って本文中に戻します。これによりテキストファイルにしても注意書きが失われません。
逆に本文中の括弧書きを脚注に変換させるマクロも考えてみました。
「（注意書き）」の「注意書き」の部分を脚注に表示します。括弧については全角括弧「（）」を想定していますが、書き換えれば「【】」や「《》」でも動作します。
当然のことかもしれませんが、編集中の文書に変更を施しますので、マクロは文書を保存してから実行してください。できればバックアップを取ってください。例によってご利用は自己責任でお願いします。

マクロ

宣言部分

括弧については全角括弧「（）」を想定しています。
「【】」や「《》」を使う場合はここを書き換えます。

Const strstart = "（"
Const strend = "）"

脚注を括弧に

脚注の注意書きを本文中に挿入します。
注意書きの取得はできたのですが、脚注位置の取得が難しいため、Wordの検索機能を利用し「^f」という脚注位置を表す特殊文字を注意書きに置換する手法を使っています。

Sub 脚注を括弧に()
Dim n As Long, kosu As Long
Dim rt As String
With ActiveDocument.Content
kosu = ActiveDocument.Footnotes.Count
For n = 1 To kosu
With ActiveDocument.Footnotes(1)
rt = .Range.Text
End With
Selection.Find.Replacement.ClearFormatting
With Selection.Find
.Text = "^f"
.Replacement.Text = strstart & rt & strend
.Wrap = wdFindContinue '処理を継続。
.MatchWildcards = False '特殊文字を検索。
End With
Selection.Find.Execute Replace:=1
Selection.Font.Superscript = False
Next n
End With
Selection.HomeKey Unit:=wdStory
End Sub

2014年9月1日追記
上のマクロについては改良版があります。

括弧を脚注に

本文中の括弧書きを脚注に変換します。
括弧書きの部分をワイルドカードを使って検索し、位置と文字列を取得、文字列の括弧を削除して、注意書きとしてセットするという手法です。

Sub 括弧を脚注に()
Dim kekka As Boolean
Dim mojiretsu As String
Do
Selection.HomeKey Unit:=wdStory
Selection.Find.ClearFormatting
With Selection.Find
.Text = strstart & "*" & strend
.Replacement.Text = ""
.MatchPhrase = False '以下4行はワイルドカード使用時の矛盾回避のため。
.MatchSoundsLike = False
.MatchAllWordForms = False
.MatchFuzzy = False
.MatchWildcards = True
End With
kekka = Selection.Find.Execute
If kekka Then
'検索結果を整形。
mojiretsu = Selection.Text
mojiretsu = Replace(mojiretsu, strstart, "")
mojiretsu = Replace(mojiretsu, strend, "")
Selection.Cut
With Selection
With .FootnoteOptions
.Location = wdBottomOfPage
.NumberingRule = wdRestartContinuous
.StartingNumber = 1
.NumberStyle = wdNoteNumberStyleArabic
End With
.Footnotes.Add Range:=Selection.Range, Reference:=""
End With
Selection.TypeText Text:=mojiretsu
End If
Loop Until kekka = False
End Sub

括弧書きならばすべて変換してしまうので、通常の括弧は半角括弧、脚注にしたい部分は全角括弧やその他の記号を使うなど区別してください。あるいは変換したい部分だけ別文書にコピーしてマクロを実行してから戻すという方法も考えられます。

Wordの脚注一覧を作成するマクロ

stabucky — Wed, 20 Feb 2013 11:53:53 +0000

Word文書中の脚注を一覧にまとめるマクロです。
脚注の文字列を集めて、文書の最後に挿入します。

Sub 脚注一覧作成()
Dim n, i As Long
Dim rt As String
With ActiveDocument.Content
.InsertAfter "【脚注一覧】"
.InsertParagraphAfter
For n = 1 To ActiveDocument.Footnotes.Count
With ActiveDocument.Footnotes(n)
i = .Index
rt = .Range.Text
End With
.InsertAfter i & ">" & rt
.InsertParagraphAfter
Next n
End With
End Sub

Writerで脚注挿入にショートカットを割り当てる

stabucky — Fri, 25 Jan 2013 22:21:54 +0000

Wordの場合、Ctrl+Alt+Fで脚注が挿入できます。
Writerの場合は、このようなキーボードショートカットがありませんが、カスタマイズで設定することができます。LibreOffice3.6.4.3で確認しました。

ツール-カスタマイズを選択。
カスタマイズダイアログでキーボードタグを選択。
ショートカットキーでCtrl+Alt+Fを選択。
範囲で挿入を選択、機能で脚注/文末脚注の直接挿入を選択。
変更をクリック。
OKをクリック。カスタマイズダイアログを閉じる。

脚注だけでなく色々と設定できます。

脚注 | You Look Too Cool